站长资源 操作系统

win10 TH2秋季正式版更新怎么激活?

整理:jimmy2024/11/7浏览2次

简介最近，微软发布了 Win10 问世以来首个重大更新 TH2，使得 Win10 的稳定性和速度都有了极大地提高。据传，升级到 TH2 以后，系统响应速度已经比 Win7 提高 30%。不过，不少细心的朋友可能也已发现，升级以后，以前使用各种方法激活的系统又变回了未激活状态，真叫人不得不仰天长叹。那么，

最近，微软发布了 Win10 问世以来首个重大更新 TH2，使得 Win10 的稳定性和速度都有了极大地提高。据传，升级到 TH2 以后，系统响应速度已经比 Win7 提高 30%。不过，不少细心的朋友可能也已发现，升级以后，以前使用各种方法激活的系统又变回了未激活状态，真叫人不得不仰天长叹。那么，怎样才能激活 Windows 10 TH2 呢？

1、首先，在 Win10 中随便打开一个文件夹，再将“查看”菜单下的“文件扩展名”勾选上。如果已经勾选，此步可省略。

2、在桌面右击鼠标，新建一个文本文档。

3、在文档里面粘贴如上图所示的内容（本文提供txt下载，注意地址中小写字母 l 和数字 1 的区别）。

txt下载：点击下载

txt内容复制：

复制内容到剪贴板

@echo off&setlocal EnableDelayedExpansion&color 3e
title KMS_Activation for Windows 10 - (hnfeng)
echo ::::::::::::::::::::::::::::::::::::::::::::::::
echo :: 自动检查 Win10 的版本，导入相应的 KMS 密钥 ::
echo :: ::
echo :: 然后连接指定的 KMS 服务器激活 Win10 ::
echo :: ::
echo :: 2015-7, hnfeng ::
echo ::::::::::::::::::::::::::::::::::::::::::::::::
echo.&echo.
set KMS_Sev=kms.landiannews.com
call :verchk
call :adminchk
set Core=TX9XD-98N7V-6WMQ6-BX7FG-H8Q99
set CoreCountrySpecific=PVMJN-6DFY6-9CCP6-7BKTT-D3WVR
set CoreN=3KHY7-WNT83-DGQKR-F7HPR-844BM
set CoreSingleLanguage=7HNRX-D7KGG-3K4RQ-4WPJ4-YTDFH
set Professional=W269N-WFGWX-YVC9B-4J6C9-T83GX
set ProfessionalN=MH37W-N47XK-V7XM9-C7227-GCQG9
set Enterprise=NPPR9-FWDCX-D2C8J-H872K-2YT43
set EnterpriseN=DPH2V-TTNVB-4X9Q3-TJR4H-KHJW4
set Education=NW6C2-QMPVW-D7KKK-3GKT6-VCFB2
set EducationN=2WH4N-8QGBV-H22JP-CT43Q-MDWWJ
set EnterpriseS=WNMTR-4C88C-JK8YV-HQ7T2-76DF9
set EnterpriseSN=2F77B-TNFGY-69QQF-B8YKP-D69TJ
for /f "tokens=3 delims= " %%i in ('reg QUERY "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion" /v "EditionID"') do set EditionID=%%i
if defined %EditionID% (
cscript //Nologo %windir%\system32\slmgr.vbs /ipk !%EditionID%!
cscript //Nologo %windir%\system32\slmgr.vbs /skms %KMS_Sev%
cscript //Nologo %windir%\system32\slmgr.vbs /ato
) else (
echo.&echo Not found DEFINED Key: "%EditionID%".
echo.
)
pause
exit
:verchk
ver | find "10.0." >nul 2>nul && (goto :EOF)
echo.&echo The current OS is NOT Windows 10.
echo.&pause
exit
:adminchk
reg query "HKU\S-1-5-19" >nul 2>nul || (
cls&echo.&echo Run as ADMINISTRATOR, Pls.
echo.&echo Press any key to exit.
echo.&pause>nul
exit)
goto :EOF